home *** CD-ROM | disk | FTP | other *** search
/ PC World Komputer 2010 April / PCWorld0410.iso / hity wydania / Ubuntu 9.10 PL / karmelkowy-koliberek-desktop-9.10-i386-PL.iso / casper / filesystem.squashfs / usr / bin / piconv < prev    next >
Text File  |  2009-10-01  |  7KB  |  271 lines
  1. #!/usr/bin/perl
  2.     eval 'exec /usr/bin/perl -S $0 ${1+"$@"}'
  3.     if $running_under_some_shell;
  4. #!./perl
  5. # $Id: piconv,v 2.3 2007/04/06 12:53:41 dankogai Exp $
  6. #
  7. use 5.8.0;
  8. use strict;
  9. use Encode ;
  10. use Encode::Alias;
  11. my %Scheme =  map {$_ => 1} qw(from_to decode_encode perlio);
  12.  
  13. use File::Basename;
  14. my $name = basename($0);
  15.  
  16. use Getopt::Long qw(:config no_ignore_case);
  17.  
  18. my %Opt;
  19.  
  20. help()
  21.     unless
  22.       GetOptions(\%Opt,
  23.          'from|f=s',
  24.          'to|t=s',
  25.          'list|l',
  26.          'string|s=s',
  27.          'check|C=i',
  28.          'c',
  29.          'perlqq|p',
  30.          'htmlcref',
  31.          'xmlcref',
  32.          'debug|D',
  33.          'scheme|S=s',
  34.          'resolve|r=s',
  35.          'help',
  36.          );
  37.  
  38. $Opt{help} and help();
  39. $Opt{list} and list_encodings();
  40. my $locale = $ENV{LC_CTYPE} || $ENV{LC_ALL} || $ENV{LANG};
  41. defined $Opt{resolve} and resolve_encoding($Opt{resolve});
  42. $Opt{from} || $Opt{to} || help();
  43. my $from = $Opt{from} || $locale or help("from_encoding unspecified");
  44. my $to   = $Opt{to}   || $locale or help("to_encoding unspecified");
  45. $Opt{string} and Encode::from_to($Opt{string}, $from, $to) and print $Opt{string} and exit;
  46. my $scheme = exists $Scheme{$Opt{scheme}} ? $Opt{scheme} :  'from_to';
  47. $Opt{check} ||= $Opt{c};
  48. $Opt{perlqq}   and $Opt{check} = Encode::PERLQQ;
  49. $Opt{htmlcref} and $Opt{check} = Encode::HTMLCREF;
  50. $Opt{xmlcref}  and $Opt{check} = Encode::XMLCREF;
  51.  
  52. if ($Opt{debug}){
  53.     my $cfrom = Encode->getEncoding($from)->name;
  54.     my $cto   = Encode->getEncoding($to)->name;
  55.     print <<"EOT";
  56. Scheme: $scheme
  57. From:   $from => $cfrom
  58. To:     $to => $cto
  59. EOT
  60. }
  61.  
  62. # we do not use <> (or ARGV) for the sake of binmode()
  63. @ARGV or push @ARGV, \*STDIN;
  64.  
  65. unless ( $scheme eq 'perlio' ) {
  66.     binmode STDOUT;
  67.     for my $argv (@ARGV) {
  68.         my $ifh = ref $argv ? $argv : undef;
  69.         $ifh or open $ifh, "<", $argv or next;
  70.         binmode $ifh;
  71.         if ( $scheme eq 'from_to' ) {    # default
  72.             while (<$ifh>) {
  73.                 Encode::from_to( $_, $from, $to, $Opt{check} );
  74.                 print;
  75.             }
  76.         }
  77.         elsif ( $scheme eq 'decode_encode' ) {    # step-by-step
  78.             while (<$ifh>) {
  79.                 my $decoded = decode( $from, $_, $Opt{check} );
  80.                 my $encoded = encode( $to, $decoded );
  81.                 print $encoded;
  82.             }
  83.         }
  84.         else {                                    # won't reach
  85.             die "$name: unknown scheme: $scheme";
  86.         }
  87.     }
  88. }
  89. else {
  90.  
  91.     # NI-S favorite
  92.     binmode STDOUT => "raw:encoding($to)";
  93.     for my $argv (@ARGV) {
  94.         my $ifh = ref $argv ? $argv : undef;
  95.         $ifh or open $ifh, "<", $argv or next;
  96.         binmode $ifh => "raw:encoding($from)";
  97.         print while (<$ifh>);
  98.     }
  99. }
  100.  
  101. sub list_encodings {
  102.     print join( "\n", Encode->encodings(":all") ), "\n";
  103.     exit 0;
  104. }
  105.  
  106. sub resolve_encoding {
  107.     if ( my $alias = Encode::resolve_alias( $_[0] ) ) {
  108.         print $alias, "\n";
  109.         exit 0;
  110.     }
  111.     else {
  112.         warn "$name: $_[0] is not known to Encode\n";
  113.         exit 1;
  114.     }
  115. }
  116.  
  117. sub help {
  118.     my $message = shift;
  119.     $message and print STDERR "$name error: $message\n";
  120.     print STDERR <<"EOT";
  121. $name [-f from_encoding] [-t to_encoding] [-s string] [files...]
  122. $name -l
  123. $name -r encoding_alias
  124.   -l,--list
  125.      lists all available encodings
  126.   -r,--resolve encoding_alias
  127.     resolve encoding to its (Encode) canonical name
  128.   -f,--from from_encoding  
  129.      when omitted, the current locale will be used
  130.   -t,--to to_encoding    
  131.      when omitted, the current locale will be used
  132.   -s,--string string         
  133.      "string" will be the input instead of STDIN or files
  134. The following are mainly of interest to Encode hackers:
  135.   -D,--debug          show debug information
  136.   -C N | -c           check the validity of the input
  137.   -S,--scheme scheme  use the scheme for conversion
  138. Those are handy when you can only see ascii characters:
  139.   -p,--perlqq
  140.   --htmlcref
  141.   --xmlcref
  142. EOT
  143.     exit;
  144. }
  145.  
  146. __END__
  147.  
  148. =head1 NAME
  149.  
  150. piconv -- iconv(1), reinvented in perl
  151.  
  152. =head1 SYNOPSIS
  153.  
  154.   piconv [-f from_encoding] [-t to_encoding] [-s string] [files...]
  155.   piconv -l
  156.   piconv [-C N|-c|-p]
  157.   piconv -S scheme ...
  158.   piconv -r encoding
  159.   piconv -D ...
  160.   piconv -h
  161.  
  162. =head1 DESCRIPTION
  163.  
  164. B<piconv> is perl version of B<iconv>, a character encoding converter
  165. widely available for various Unixen today.  This script was primarily
  166. a technology demonstrator for Perl 5.8.0, but you can use piconv in the
  167. place of iconv for virtually any case.
  168.  
  169. piconv converts the character encoding of either STDIN or files
  170. specified in the argument and prints out to STDOUT.
  171.  
  172. Here is the list of options.  Each option can be in short format (-f)
  173. or long (--from).
  174.  
  175. =over 4
  176.  
  177. =item -f,--from from_encoding
  178.  
  179. Specifies the encoding you are converting from.  Unlike B<iconv>,
  180. this option can be omitted.  In such cases, the current locale is used.
  181.  
  182. =item -t,--to to_encoding
  183.  
  184. Specifies the encoding you are converting to.  Unlike B<iconv>,
  185. this option can be omitted.  In such cases, the current locale is used.
  186.  
  187. Therefore, when both -f and -t are omitted, B<piconv> just acts
  188. like B<cat>.
  189.  
  190. =item -s,--string I<string>
  191.  
  192. uses I<string> instead of file for the source of text.
  193.  
  194. =item -l,--list
  195.  
  196. Lists all available encodings, one per line, in case-insensitive
  197. order.  Note that only the canonical names are listed; many aliases
  198. exist.  For example, the names are case-insensitive, and many standard
  199. and common aliases work, such as "latin1" for "ISO-8859-1", or "ibm850"
  200. instead of "cp850", or "winlatin1" for "cp1252".  See L<Encode::Supported>
  201. for a full discussion.
  202.  
  203. =item -C,--check I<N>
  204.  
  205. Check the validity of the stream if I<N> = 1.  When I<N> = -1, something
  206. interesting happens when it encounters an invalid character.
  207.  
  208. =item -c
  209.  
  210. Same as C<-C 1>.
  211.  
  212. =item -p,--perlqq
  213.  
  214. =item --htmlcref
  215.  
  216. =item --xmlcref
  217.  
  218. Applies PERLQQ, HTMLCREF, XMLCREF, respectively.  Try
  219.  
  220.   piconv -f utf8 -t ascii --perlqq
  221.  
  222. To see what it does.
  223.  
  224. =item -h,--help
  225.  
  226. Show usage.
  227.  
  228. =item -D,--debug
  229.  
  230. Invokes debugging mode.  Primarily for Encode hackers.
  231.  
  232. =item -S,--scheme scheme
  233.  
  234. Selects which scheme is to be used for conversion.  Available schemes
  235. are as follows:
  236.  
  237. =over 4
  238.  
  239. =item from_to
  240.  
  241. Uses Encode::from_to for conversion.  This is the default.
  242.  
  243. =item decode_encode
  244.  
  245. Input strings are decode()d then encode()d.  A straight two-step
  246. implementation.
  247.  
  248. =item perlio
  249.  
  250. The new perlIO layer is used.  NI-S' favorite.
  251.  
  252. You should use this option if you are using UTF-16 and others which
  253. linefeed is not $/.
  254.  
  255. =back
  256.  
  257. Like the I<-D> option, this is also for Encode hackers.
  258.  
  259. =back
  260.  
  261. =head1 SEE ALSO
  262.  
  263. L<iconv/1>
  264. L<locale/3>
  265. L<Encode>
  266. L<Encode::Supported>
  267. L<Encode::Alias>
  268. L<PerlIO>
  269.  
  270. =cut
  271.